define printOut {
#   t_print ($1 "\n")
    write_file ($1 "\n", "/tmp/pipe")
    }
    
define changeDir {
    $current_dir = $1
    }
    
define byteForLine {
    nlines = $1 - 1
    for (i=0; i<$text_length && nlines != 0; i++)
        if (get_character (i) == "\n")
            nlines--
    return i
    }
    
define showByte {
    open ($1)
    set_cursor_pos ($2)
    }

define showLine {
    open ($1)
    set_cursor_pos (byteForLine ($2))
    }

define showMethod {
    open ($1)
    pos = search ($2, 0)
    set_cursor_pos (pos)
    }    

define showSelection {
    open ($1)
    pos = search ($2, 0)
    set_cursor_pos (pos)
    select (pos, pos+length($2))
    }
    
define insertText {
    replace_range ($cursor, $cursor, $1)
    }

define newFile {
    new()
    insertText ($2)
    save_as ($1)
    printOut (0)
    }
    
define reload {
    open ($file_path $file_name)
    }

define setDebugPos {
    if ($1 != "") {
        open ($1)
        pos = byteForLine ($2)
        set_cursor_pos (pos)
        
        end = pos
        while (get_character (end) != "\n") 
            end++
            
        select (pos, end)
        }
    else
        set_cursor_pos (0)        
    }
    
define addBreakpoint {
    setDebugPos ($1, $2)
    }

define resetDebugging {
    select ($cursor, $cursor)
    }
    
define clear {
    close()
    }
    
define getLine {
    printOut ($line)    
    }

define getFilename {
    printOut ($file_path $file_name)
    }
    
define getSelection {
    printOut (get_selection())
    }