dnl
dnl	Copyright (c) 1993,1997 JSC Rinet - Novosibirsk, Russia
dnl
dnl Redistribution and use in source forms, with and without modification,
dnl are permitted provided that this entire comment appears intact.
dnl Redistribution in binary form may occur without any restrictions.
dnl
dnl THIS SOFTWARE IS PROVIDED ``AS IS'' WITHOUT ANY WARRANTIES OF ANY KIND.
dnl

dnl
dnl configure.in -- template for ./configure
dnl Process this file with `autoconf' to produce a configure script
dnl	remember to edit configure.in, not ./configure
dnl

AC_INIT(trafshow.c)
AC_CONFIG_HEADER(config.h)

AC_CANONICAL_SYSTEM

AC_LBL_C_INIT(V_CCOPT, V_INCLS)

AC_CHECK_HEADERS(sys/ioctl.h sys/mbuf.h net/slip.h)
AC_HEADER_TIME

AC_LBL_CHECK_TYPE(u_int32_t, u_int)

AC_CHECK_FUNCS(siginterrupt select)
AC_REPLACE_FUNCS(strcasecmp)

dnl autoconf will generate a warning here.
AC_C_BIGENDIAN

AC_LBL_UNALIGNED_ACCESS

dnl termcap library may be required.
AC_CHECK_LIB(termcap, tgetent)

AC_MSG_CHECKING(for curses library)
AC_CACHE_VAL(ac_cv_have_curses,
	ac_cv_save_CFLAGS="$CFLAGS"
	ac_cv_save_LIBS="$LIBS"
	LIBS="-lslang $ac_cv_save_LIBS"
	AC_TRY_LINK([#include <slcurses.h>],[initscr();],
	ac_cv_have_curses="slang",
		LIBS="-lncurses $ac_cv_save_LIBS"
		AC_TRY_LINK([#include <ncurses.h>], [initscr();],
		ac_cv_have_curses="ncurses",
			CFLAGS="-I/usr/include/ncurses $ac_cv_save_CFLAGS"
			AC_TRY_LINK([#include <ncurses.h>], [initscr();],
			ac_cv_have_curses="n_curses",
				LIBS="-lcurses $ac_cv_save_LIBS"
				AC_TRY_LINK([#include <curses.h>], [initscr();],
				ac_cv_have_curses="curses",
					ac_cv_have_curses="none"
				)
			)
		)
	)
	CFLAGS="$ac_cv_save_CFLAGS"
)
AC_MSG_RESULT($ac_cv_have_curses)

case "$ac_cv_have_curses" in

slang)
	AC_DEFINE(HAVE_SLCURSES)
	AC_DEFINE(HAVE_HAS_COLORS)
	;;
ncurses)
	AC_DEFINE(HAVE_NCURSES)
	AC_CHECK_FUNCS(has_colors)
	AC_CHECK_FUNCS(bkgd wbkgd resizeterm)
	;;
n_curses)
	V_INCLS="-I/usr/include/ncurses $V_INCLS"
	AC_DEFINE(HAVE_NCURSES)
	AC_CHECK_FUNCS(has_colors)
	AC_CHECK_FUNCS(bkgd wbkgd resizeterm)
	;;
curses)
	AC_DEFINE(HAVE_CURSES)
	AC_CHECK_FUNCS(has_colors)
	AC_CHECK_FUNCS(bkgd wbkgd resizeterm)
	;;
*)
	AC_MSG_ERROR(cannot find curses; see the INSTALL notes)
	;;
esac

AC_LBL_LIBPCAP(V_PCAPDEP, V_INCLS)

AC_MSG_CHECKING(for pcap version)
AC_CACHE_VAL(V_PCAPVER,
	AC_TRY_RUN(
[#include <stdio.h>
extern char pcap_version[[]];
int main(argc, argv) int argc; char **argv;
{ if (argc>1) puts(pcap_version); return 0; }],
	V_PCAPVER=`./conftest vers`, V_PCAPVER="unknown")
)
AC_MSG_RESULT($V_PCAPVER)

V_GROUP=0
case "$target_os" in

freebsd*)
	AC_DEFINE(HAVE_RTF_LLINFO)
	;;
bsdi2*)
	AC_DEFINE(HAVE_RTF_LLINFO)
	;;
bsdi3*)
	V_GROUP=kmem
	AC_DEFINE(HAVE_RTF_LLINFO)
	;;
irix*)
	V_GROUP=sys
	;;
linux*)
	AC_MSG_CHECKING(Linux kernel version)
	AC_CACHE_VAL(ac_cv_linux_vers,
	    ac_cv_linux_vers=`uname -r 2>&1 | \
		sed -n -e '$s/.* //' -e '$s/\..*//p'`)
	AC_MSG_RESULT($ac_cv_linux_vers)
	if test $ac_cv_linux_vers -lt 2 ; then
		AC_MSG_ERROR(version 2 or higher required; see the INSTALL notes)
	fi
	V_INCLS="-Ilinux $V_INCLS"
	AC_DEFINE(HAVE_PROC_NET_ARP)
	;;
osf*)
	V_GROUP=system
	dnl fake for ip_hl problem
	AC_DEFINE(__STDC__,2)
	;;
solaris*)
	V_GROUP=sys
	;;
esac

if test -f /dev/bpf0 ; then
	V_GROUP=bpf
fi

AC_SUBST(V_CCOPT)
AC_SUBST(V_INCLS)
AC_SUBST(V_PCAPDEP)
AC_SUBST(V_PCAPVER)
AC_SUBST(V_GROUP)

AC_OUTPUT(Makefile)

exit 0